MSSQL 相关
topcss opened this issue · comments
SQLSERVER存储过程基本语法
一、定义变量
--简单赋值
declare @a int
set @a=5
print @a
--使用select语句赋值
declare @user1 nvarchar(50)
select @user1='张三'
print @user1
declare @user2 nvarchar(50)
select @user2 = Name from ST_User where ID=1
print @user2
--使用update语句赋值
declare @user3 nvarchar(50)
update ST_User set @user3 = Name where ID=1
print @user3
二、表、临时表、表变量
--创建临时表1
create table #DU_User1
(
[ID] [int] NOT NULL,
[Oid] [int] NOT NULL,
[Login] [nvarchar](50) NOT NULL,
[Rtx] [nvarchar](4) NOT NULL,
[Name] [nvarchar](5) NOT NULL,
[Password] [nvarchar](max) NULL,
[State] [nvarchar](8) NOT NULL
);
--向临时表1插入一条记录
insert into #DU_User1 (ID,Oid,[Login],Rtx,Name,[Password],State) values (100,2,'LS','0000','临时','321','特殊');
--从ST_User查询数据，填充至新生成的临时表
select * into #DU_User2 from ST_User where ID<8
--查询并联合两临时表
select * from #DU_User2 where ID<3 union select * from #DU_User1
--删除两临时表
drop table #DU_User1
drop table #DU_User2
--创建临时表
CREATE TABLE #t
(
[ID] [int] NOT NULL,
[Oid] [int] NOT NULL,
[Login] [nvarchar](50) NOT NULL,
[Rtx] [nvarchar](4) NOT NULL,
[Name] [nvarchar](5) NOT NULL,
[Password] [nvarchar](max) NULL,
[State] [nvarchar](8) NOT NULL,
)
--将查询结果集（多条数据）插入临时表
insert into #t select * from ST_User
--不能这样插入
--select * into #t from dbo.ST_User
--添加一列，为int型自增长子段
alter table #t add [myid] int NOT NULL IDENTITY(1,1)
--添加一列，默认填充全球唯一标识
alter table #t add [myid1] uniqueidentifier NOT NULL default(newid())
select * from #t
drop table #t
--给查询结果集增加自增长列
--无主键时：
select IDENTITY(int,1,1)as ID, Name,[Login],[Password] into #t from ST_User
select * from #t
--有主键时：
select (select SUM(1) from ST_User where ID<= a.ID) as myID,* from ST_User a order by myID
--定义表变量
declare @t table
(
id int not null,
msg nvarchar(50) null
)
insert into @t values(1,'1')
insert into @t values(2,'2')
select * from @t
三、循环
--while循环计算1到100的和
declare @a int
declare @sum int
set @a=1
set @sum=0
while @a<=100
begin
set @sum+=@a
set @a+=1
end
print @sum
四、条件语句
--if,else条件分支
if(1+1=2)
begin
print '对'
end
else
begin
print '错'
end
--when then条件分支
declare @today int
declare @week nvarchar(3)
set @today=3
set @week=case
when @today=1 then '星期一'
when @today=2 then '星期二'
when @today=3 then '星期三'
when @today=4 then '星期四'
when @today=5 then '星期五'
when @today=6 then '星期六'
when @today=7 then '星期日'
else '值错误'
end
print @week
五、游标
declare @ID int
declare @Oid int
declare @Login varchar(50)
--定义一个游标
declare user_cur cursor for select ID,Oid,[Login] from ST_User
--打开游标
open user_cur
while @@fetch_status=0
begin
--读取游标
fetch next from user_cur into @ID,@Oid,@Login
print @ID
--print @Login
end
close user_cur
--摧毁游标
deallocate user_cur
六、触发器
触发器中的临时表：
Inserted
存放进行insert和update 操作后的数据
Deleted
存放进行delete 和update操作前的数据
--创建触发器
Create trigger User_OnUpdate
On ST_User
for Update
As
declare @msg nvarchar(50)
--@msg记录修改情况
select @msg = N'姓名从“' + Deleted.Name + N'”修改为“' + Inserted.Name + '”' from Inserted,Deleted
--插入日志表
insert into [LOG](MSG)values(@msg)
--删除触发器
drop trigger User_OnUpdate
七、存储过程
--创建带output参数的存储过程
CREATE PROCEDURE PR_Sum
@a int,
@b int,
@sum int output
AS
BEGIN
set @sum=@a+@b
END
--创建Return返回值存储过程
CREATE PROCEDURE PR_Sum2
@a int,
@b int
AS
BEGIN
Return @a+@b
END
--执行存储过程获取output型返回值
declare @mysum int
execute PR_Sum 1,2,@mysum output
print @mysum
--执行存储过程获取Return型返回值
declare @mysum2 int
execute @mysum2= PR_Sum2 1,2
print @mysum2
八、自定义函数
函数的分类：
1）标量值函数
2）表值函数
a:内联表值函数
b:多语句表值函数
3）系统函数
--新建标量值函数
create function FUNC_Sum1
(
@a int,
@b int
)
returns int
as
begin
return @a+@b
end
--新建内联表值函数
create function FUNC_UserTab_1
(
@myId int
)
returns table
as
return (select * from ST_User where ID<@myId)
--新建多语句表值函数
create function FUNC_UserTab_2
(
@myId int
)
returns @t table
(
[ID] [int] NOT NULL,
[Oid] [int] NOT NULL,
[Login] [nvarchar](50) NOT NULL,
[Rtx] [nvarchar](4) NOT NULL,
[Name] [nvarchar](5) NOT NULL,
[Password] [nvarchar](max) NULL,
[State] [nvarchar](8) NOT NULL
)
as
begin
insert into @t select * from ST_User where ID<@myId
return
end
--调用表值函数
select * from dbo.FUNC_UserTab_1(15)
--调用标量值函数
declare @s int
set @s=dbo.FUNC_Sum1(100,50)
print @s
--删除标量值函数
drop function FUNC_Sum1
谈谈自定义函数与存储过程的区别：
一、自定义函数：
1. 可以返回表变量
2. 限制颇多，包括
不能使用output参数；
不能用临时表；
函数内部的操作不能影响到外部环境；
不能通过select返回结果集；
不能update，delete，数据库表；
3. 必须return 一个标量值或表变量
自定义函数一般用在复用度高，功能简单单一，争对性强的地方。
二、存储过程
1. 不能返回表变量
2. 限制少，可以执行对数据库表的操作，可以返回数据集
3. 可以return一个标量值，也可以省略return
存储过程一般用在实现复杂的功能，数据操纵方面。
开窗函数over()的语法
SELECT [OrderID] --订单id
,[CustomerID] --客户id
,[Freight] --运费
,COUNT(OrderID) over() as totalNum --一所有订单的总数
,SUM(Freight) over(partition by customerid) as cusTotalFreight --每一个客户的总运费
,SUM(Freight) over() as totalFreight --所有客户的总运费
,AVG(Freight) over(partition by customerid) as cusAvgFreight --每一个客户的平均运费
,AVG(Freight) over() as avgFreight --所有客户的平均运费
,MAX(Freight) over(partition by customerid) as cusMaxFreight --每一个客户所有订单中最大的运费
,MAX(Freight) over() as maxFreight --所有客户中最大运费
,MIN(Freight) over(partition by customerid) as cusMinFreight --每一个客户所有订单中最小的运费
,MIN(Freight) over() as minFreight --所有客户中最小运费
FROM [Northwind].[dbo].[Orders]
SELECT
-- 利用开创函数来分组和排序
ROW_NUMBER() OVER(PARTITION BY A.ZKBH ORDER BY CAST(QYSD AS NUMERIC)) AS NUM
FROM TAB1
SQL server 中的@，@@、#，##分别代表什么？
@ 局部变量
@@ 系统级变量
# 本地临时表
## 全局临时表
为某表添加几个系统字段
declare @tableName nvarchar(255)
-- TODO：此处修改表名
set @tableName = '表名1'
exec('ALTER TABLE [dbo].[' + @tableName + '] ADD [SYSCJZ] nvarchar(255) NULL;')
exec('ALTER TABLE [dbo].[' + @tableName + '] ADD [SYSCJDW] nvarchar(255) NULL;')
exec('ALTER TABLE [dbo].[' + @tableName + '] ADD [SYSCJSJ] nvarchar(255) NULL;')
exec('ALTER TABLE [dbo].[' + @tableName + '] ADD [SYSGXZ] nvarchar(255) NULL;')
exec('ALTER TABLE [dbo].[' + @tableName + '] ADD [SYSGXDW] nvarchar(255) NULL;')
exec('ALTER TABLE [dbo].[' + @tableName + '] ADD [SYSGXSJ] nvarchar(255) NULL;')
exec('EXEC sp_addextendedproperty ''MS_Description'', N''创建者，含用户ID和用户名，格式为用户名（用户ID）'', ''SCHEMA'', N''dbo'', ''TABLE'', N''' + @tableName + ''', ''COLUMN'', N''SYSCJZ'';')
exec('EXEC sp_addextendedproperty ''MS_Description'', N''创建单位'', ''SCHEMA'', N''dbo'', ''TABLE'', N''' + @tableName + ''', ''COLUMN'', N''SYSCJDW'';')
exec('EXEC sp_addextendedproperty ''MS_Description'', N''创建时间'', ''SCHEMA'', N''dbo'', ''TABLE'', N''' + @tableName + ''', ''COLUMN'', N''SYSCJSJ'';')
exec('EXEC sp_addextendedproperty ''MS_Description'', N''更新者'', ''SCHEMA'', N''dbo'', ''TABLE'', N''' + @tableName + ''', ''COLUMN'', N''SYSGXZ'';')
exec('EXEC sp_addextendedproperty ''MS_Description'', N''更新单位'', ''SCHEMA'', N''dbo'', ''TABLE'', N''' + @tableName + ''', ''COLUMN'', N''SYSGXDW'';')
exec('EXEC sp_addextendedproperty ''MS_Description'', N''更新时间'', ''SCHEMA'', N''dbo'', ''TABLE'', N''' + @tableName + ''', ''COLUMN'', N''SYSGXSJ'';')Split功能分割字符串
-- Split功能分割字符串
-- https://www.cnblogs.com/liugh/articles/8419861.html
create FUNCTION dbo.splitl (
@String VARCHAR(MAX),
@Delimiter VARCHAR(MAX)
) RETURNS @temptable TABLE (items VARCHAR(MAX)) AS
BEGIN
DECLARE @idx INT=1
DECLARE @slice VARCHAR(MAX)
IF LEN(@String) < 1 OR LEN(ISNULL(@String,'')) = 0
RETURN
WHILE @idx != 0
BEGIN
SET @idx = CHARINDEX(@Delimiter,@String)
IF @idx != 0
SET @slice = LEFT(@String,@idx - 1)
ELSE
SET @slice = @String
IF LEN(@slice) > 0
INSERT INTO @temptable(items) VALUES(@slice)
SET @String = RIGHT (@String, LEN(@String) - @idx)
IF LEN(@String) = 0
BREAK
END
RETURN
END
-- 测试
SELECT * from splitl('b945d163,5134,145e,d9a0,336a7b42e489', ',')-- 保留2位小数的随机数
SELECT Round(rand()*5,2)
select cast('9.78' as float) = 9.779999999999999
select cast(NULL as float) = NULL
select cast('' as float) = 0
select cast('9.78' as numeric(10,2)) = 9.78
select cast('9.78' as decimal(10,6)) = 9.78
-- 不包含的写法：
where aa not like '%关键字%' 让睡起的数据，站起来
SELECT P.* from (
SELECT
'KLMD' AS 'NAME', -- 列名
MAX(KLMD) as 'MAX', -- 最大值
MIN(KLMD) as 'MIN', -- 最小值
AVG(KXL) as 'AVG', -- 平均值
STDEV(KXL) as 'BZC', -- 标准差
(STDEV(KXL)/AVG(KXL)) as 'BYXS', -- 变异系数
CAST(COUNT(KXL) AS FLOAT) as 'YBS', -- 样本数
((1-(1.704/SQRT(COUNT(KLMD))+4.678/(COUNT(KLMD)*COUNT(KLMD)))*(STDEV(KLMD)/AVG(KLMD)))*AVG(KLMD)) as 'BZZ' -- 标准值
FROM TABLE1
where KLMD IS NOT NULL AND KLMD not like '*%'
GROUP BY GROUPID) as T
UNPIVOT
(
KLMD FOR TITLE IN
(MAX, MIN, AVG, BZC, BYXS, YBS, BZZ)
) P